4.1 Installing from MELPA

Org-roam is available from Melpa and Melpa-Stable. If you haven’t used Emacs’ package manager before, you may familiarize yourself with it by reading the documentation in the Emacs manual, see (emacs)Packages. Then, add one of the archives to ‘package-archives’:

• To use Melpa:

(require 'package)
(add-to-list 'package-archives
             '("melpa" . "http://melpa.org/packages/") t)

• To use Melpa-Stable:

(require 'package)
(add-to-list 'package-archives
             '("melpa-stable" . "http://stable.melpa.org/packages/") t)

Org-roam also depends on a recent version of Org, which can be obtained in Org’s package repository (see (org)Installation).

Once you have done that, you can install Org-roam and its dependencies using:

M-x package-install RET org-roam RET

4.2 Installing from Source

You may install Org-roam directly from the repository on GitHub if you like. This will give you access to the latest version hours or days before it appears on MELPA, and months (or more) before it is added to the Debian or Ubuntu repositories. This will also give you access to various developmental branches that may be available.

Note, however, that development version, and especially any feature branches, may not always be in working order. You’ll need to be prepared to do some debugging, or to manually roll-back to working versions, if you install from GitHub.

Installing from GitHub requires that you clone the repository:

git clone https://github.com/org-roam/org-roam.git /path/to/org/roam

where ./path/to/org/roam is the location you will store your copy of the code.

Next, you need to add this location to your load path, and require the Org-roam library. Add the following code to your .emacs:

(add-to-list 'load-path "/path/to/org/roam")
(require 'org-roam)

You now have Org-roam installed. However, you don’t necessarily have the dependencies that it requires. These include:

• dash
• f
• s
• org
• emacsql
• emacsql-sqlite
• magit-section

You can install this manually as well, or get the latest version from MELPA. You may wish to use use-package, straight.el to help manage this.

If you would like to install the manual for access from Emacs’ built-in Info system, you’ll need to compile the .texi source file, and install it in an appropriate location.

To compile the .texi source file, from a terminal navigate to the /doc subdirectory of the Org-roam repository, and run the following:

make infodir=/path/to/my/info/files install-info

Where /path/to/my/info/files is the location where you keep info files. This target directory needs to be stored in the variable ‘Info-default-directory-list‘. If you aren’t using one of the default info locations, you can configure this with the following in your .emacs file:

(require 'info)
(add-to-list 'Info-default-directory-list
             "/path/to/my/info/files")

You can also use one of the default locations, such as:

• usr/local/share/info
• usr/share/info
• usr/local/share/info

If you do this, you’ll need to make sure you have write-access to that location, or run the above make command as root.

Now that the info file is ready, you need to add it to the corresponding dir file:

install-info /path/to/my/info/files/org-roam.info /path/to/my/info/files/dir

4.3 Installation Troubleshooting

• C Compiler

5.1 The Org-roam Node

We first begin with some terminology we’ll use throughout the manual. We term the basic denomination in Org-roam a node. We define a node as follows:

A node is any headline or top level file with an ID.

For example, with this example file content:

:PROPERTIES:
:ID:       foo
:END:
#+title: Foo

* Bar
:PROPERTIES:
:ID:       bar
:END:

We create two nodes:

• A file node “Foo” with id foo.
• A headline node “Bar” with id bar.

Headlines without IDs will not be considered Org-roam nodes. Org IDs can be added to files or headlines via the interactive command M-x org-id-get-create.

5.2 Links between Nodes

We link between nodes using Org’s standard ID link (e.g. id:foo). While only ID links will be considered during the computation of links between nodes, Org-roam caches all other links in the documents for external use.

5.3 Setting up Org-roam

Org-roam’s capabilities stem from its aggressive caching: it crawls all files within org-roam-directory, and maintains a cache of all links and nodes.

To start using Org-roam, pick a location to store the Org-roam files. The directory that will contain your notes is specified by the variable org-roam-directory. Org-roam searches recursively within org-roam-directory for notes. This variable needs to be set before any calls to Org-roam functions.

For this tutorial, create an empty directory, and set org-roam-directory:

(make-directory "~/org-roam")
(setq org-roam-directory (file-truename "~/org-roam"))

The file-truename function is only necessary when you use symbolic links inside org-roam-directory: Org-roam does not resolve symbolic links. One can however instruct Emacs to always resolve symlinks, at a performance cost:

(setq find-file-visit-truename t)

Next, we setup Org-roam to run functions on file changes to maintain cache consistency. This is achieved by running M-x org-roam-db-autosync-mode. To ensure that Org-roam is available on startup, place this in your Emacs configuration:

(org-roam-db-autosync-mode)

To build the cache manually, run M-x org-roam-db-sync. Cache builds may take a while the first time, but subsequent builds are often instantaneous because they only reprocess modified files.

5.4 Creating and Linking Nodes

Org-roam makes it easy to create notes and link them together. There are 2 main functions for creating nodes:

• org-roam-node-insert: creates a node if it does not exist, and inserts a link to the node at point.
• org-roam-node-find: creates a node if it does not exist, and visits the node.
• org-roam-capture: creates a node if it does not exist, and restores the current window configuration upon completion.

Let’s first try org-roam-node-find. Calling M-x org-roam-node-find will show a list of titles for nodes that reside in org-roam-directory. It should show nothing right now, since there are no notes in the directory. Enter the title of the note you wish to create, and press RET. This begins the note creation process. This process uses org-capture’s templating system, and can be customized (see The Templating System). Using the default template, pressing C-c C-c finishes the note capture.

Now that we have a node, we can try inserting a link to the node using M-x org-roam-node-insert. This brings up the list of nodes, which should contain the node you just created. Selecting the node will insert an id: link to the node. If you instead entered a title that does not exist, you will once again be brought through the node creation process.

One can also conveniently insert links via the completion-at-point functions Org-roam provides (see Completion).

5.5 Customizing Node Completions

Node selection is achieved via the completing-read interface, typically through ‘org-roam-node-read‘. The presentation of these nodes are governed by org-roam-node-display-template.

Variable: org-roam-node-display-template ¶

Configures display formatting for Org-roam node.

Patterns of form “${field-name:length}” are interpolated based on the current node.

Each “field-name” is replaced with the return value of each corresponding accessor function for org-roam-node, e.g. “${title}” will be interpolated by the result of org-roam-node-title. You can also define custom accessors using cl-defmethod. For example, you can define:

(cl-defmethod org-roam-node-my-title ((node org-roam-node)) (concat “My ” (org-roam-node-title node)))

and then reference it here or in the capture templates as “${my-title}”.

“length” is an optional specifier and declares how many characters can be used to display the value of the corresponding field. If it’s not specified, the field will be inserted as is, i.e. it won’t be aligned nor trimmed. If it’s an integer, the field will be aligned accordingly and all the exceeding characters will be trimmed out. If it’s “*”, the field will use as many characters as possible and will be aligned accordingly.

A closure can also be assigned to this variable in which case the closure is evaluated and the return value is used as the template. The closure must evaluate to a valid template string.

If you’re using a vertical completion framework, such as Ivy and Selectrum, Org-roam supports the generation of an aligned, tabular completion interface. For example, to include a column for tags up to 10 character widths wide, one can set org-roam-node-display-template as such:

(setq org-roam-node-display-template
      (concat "${title:*} "
              (propertize "${tags:10}" 'face 'org-tag)))

6.1 How to cache

Org-roam uses a sqlite database to perform caching, but there are multiple Emacs libraries that can be used. The default used by Org-roam is emacs-sqlite. Below the pros and cons of each package is used:

emacs-sqlite

The default option used by Org-roam. This library is the most mature and well-supported and is imported by default in Org-roam.

One downside of using emacs-sqlite is that using it requires compilation and can cause issues in some environments (especially Windows). If you have issues producing the customized binary required by emacs-sqlite, consider using emacs-sqlite3.

emacs-sqlite3

emacs-sqlite3 uses the official sqlite3 binary that can be obtained from your system’s package manager. This is useful if you have issues producing the sqlite3 binary required by the other packages. However, it is not recommended because it has some compatibility issues with Emacs, but should work for most regular cases. See Chris Wellon’s blog post for more information.

To use emacsql-sqlite3, ensure that the package is installed, and set:

(setq org-roam-database-connector 'sqlite3)

emacssql-sqlite-module (previously emacsql-libsqlite3)

emacs-sqlite-module is a relatively young package which uses an Emacs module that exposes parts of the SQLite C API to Emacs Lisp, instead of using subprocess as emacsql-sqlite does. It is expected to be a more performant drop-in replacement for emacs-sqlite.

(setq org-roam-database-connector 'sqlite-module)

emacsql-sqlite-builtin

emacsql-sqlite-builtin uses the in-built SQLite support for Emacs 29 and later. This is the recommended option if you are using a version of Emacs that supports it.

(setq org-roam-database-connector 'sqlite-builtin)

6.2 What to cache

By default, all nodes (any headline or file with an ID) are cached by Org-roam. There are instances where you may want to have headlines with ID, but not have them cached by Org-roam.

To exclude a headline from the Org-roam database, set the ROAM_EXCLUDE property to a non-nil value. For example:

* Foo
  :PROPERTIES:
  :ID:       foo
  :ROAM_EXCLUDE: t
  :END:

One can also set org-roam-db-node-include-function. For example, to exclude all headlines with the ATTACH tag from the Org-roam database, one can set:

(setq org-roam-db-node-include-function
      (lambda ()
        (not (member "ATTACH" (org-get-tags)))))

Org-roam relied on the obtained Org AST for the buffer to parse links. However, links appearing in some places (e.g. within property drawers) are not considered by the Org AST to be links. Therefore, Org-roam takes special care of additionally trying to process these links. Use org-roam-db-extra-links-elements to specify which additional Org AST element types to consider.

Variable: org-roam-db-extra-links-elements ¶

The list of Org element types to include for parsing by Org-roam.

By default, when parsing Org’s AST, links within keywords and property drawers are not parsed as links. Sometimes however, it is desirable to parse and cache these links (e.g. hiding links in a property drawer).

Additionally, one may want to ignore certain keys from being excluded within property drawers. For example, we would not want ROAM_REFS links to be self-referential. Hence, to exclude specific keys, we use org-roam-db-extra-links-exclude-keys.

Variable: org-roam-db-extra-links-exclude-keys ¶

Keys to ignore when mapping over links.

The car of the association list is the Org element type (e.g. keyword). The cdr is a list of case-insensitive strings to exclude from being treated as links.

6.3 When to cache

By default, Org-roam is eager in caching: each time an Org-roam file is modified and saved, it updates the database for the corresponding file. This keeps the database up-to-date, causing the least surprise when using the interactive commands.

However, depending on how large your Org files are, database updating can be a slow operation. You can disable the automatic updating of the database by setting org-roam-db-update-on-save to nil.

Variable: org-roam-db-update-on-save ¶

If t, update the Org-roam database upon saving the file. Disable this if your files are large and updating the database is slow.

7.1 Navigating the Org-roam Buffer

The Org-roam buffer uses magit-section, making the typical magit-section keybindings available. Here are several of the more useful ones:

• M-{N}: magit-section-show-level-{N}-all
• n: magit-section-forward
• <TAB>: magit-section-toggle
• <RET>: org-roam-buffer-visit-thing

org-roam-buffer-visit-thing is a placeholder command, that is replaced by section-specific commands such as org-roam-node-visit.

7.2 Configuring what is displayed in the buffer

There are currently 3 provided widget types:

• BacklinksView (preview of) nodes that link to this node
• Reference LinksNodes that reference this node (see Refs)
• Unlinked referencesView nodes that contain text that match the nodes title/alias but are not linked

To configure what sections are displayed in the buffer, set ~org-roam-mode-sections.

(setq org-roam-mode-sections
      (list #'org-roam-backlinks-section
            #'org-roam-reflinks-section
            ;; #'org-roam-unlinked-references-section
            ))

Note that computing unlinked references may be slow, and has not been added in by default.

For each section function, you can pass args along to modify its behaviour. For example, if you want to render unique sources for backlinks (and also keep rendering reference links), set org-roam-mode-sections as follows:

(setq org-roam-mode-sections
      '((org-roam-backlinks-section :unique t)
        org-roam-reflinks-section))

7.3 Configuring the Org-roam buffer display

Org-roam does not control how the pop-up buffer is displayed: this is left to the user. The author’s recommended configuration is as follows:

(add-to-list 'display-buffer-alist
             '("\\*org-roam\\*"
               (display-buffer-in-direction)
               (direction . right)
               (window-width . 0.33)
               (window-height . fit-window-to-buffer)))

Crucially, the window is a regular window (not a side-window), and this allows for predictable navigation:

• RET navigates to thing-at-point in the current window, replacing the Org-roam buffer.
• C-u RET navigates to thing-at-point in the other window.

For users that prefer using a side-window for the org-roam buffer, the following example configuration should provide a good starting point:

(add-to-list 'display-buffer-alist
             '("\\*org-roam\\*"
               (display-buffer-in-side-window)
               (side . right)
               (slot . 0)
               (window-width . 0.33)
               (window-parameters . ((no-other-window . t)
                                     (no-delete-other-windows . t)))))

7.4 TODO Styling the Org-roam buffer

8.1 Standard Org properties

Org-roam caches most of the standard Org properties. The full list now includes:

• outline level
• todo state
• priority
• scheduled
• deadline
• tags

8.2 Titles and Aliases

Each node has a single title. For file nodes, this is specified with the ‘#+title‘ property for the file. For headline nodes, this is the main text.

Nodes can also have multiple aliases. Aliases allow searching for nodes via an alternative name. For example, one may want to assign a well-known acronym (AI) to a node titled “Artificial Intelligence”.

To assign an alias to a node, add the “ROAM_ALIASES” property to the node:

* Artificial Intelligence
:PROPERTIES:
:ROAM_ALIASES: AI
:END:

Alternatively, Org-roam provides some functions to add or remove aliases.

Function: org-roam-alias-add alias ¶

Add ALIAS to the node at point. When called interactively, prompt for the alias to add.

Function: org-roam-alias-remove ¶

Remove an alias from the node at point.

8.3 Tags

Tags for top-level (file) nodes are pulled from the variable org-file-tags, which is set by the #+filetags keyword, as well as other tags the file may have inherited. Tags for headline level nodes are regular Org tags.

Note that the #+filetags keyword results in tags being inherited by headers within the file. This makes it impossible for selective tag inheritance: i.e. either tag inheritance is turned off, or all headline nodes will inherit the tags from the file node. This is a design compromise of Org-roam.

8.4 Refs

Refs are unique identifiers for nodes. These keys allow references to the key to show up in the Org-roam buffer. For example, a node for a website may use the URL as the ref, and a node for a paper may use an Org-ref citation key.

To add a ref, add to the “ROAM_REFS” property as follows:

* Google
:PROPERTIES:
:ROAM_REFS: https://www.google.com/
:END:

With the above example, if another node links to https://www.google.com/, it will show up as a “reference backlink”.

These keys also come in useful for when taking website notes, using the roam-ref protocol (see org-roam-protocol).

You may assign multiple refs to a single node, for example when you want multiple papers in a series to share the same note, or an article has a citation key and a URL at the same time.

Org-roam also provides some functions to add or remove refs.

Function: org-roam-ref-add ref ¶

Add REF to the node at point. When called interactively, prompt for the ref to add.

Function: org-roam-ref-remove ¶

Remove a ref from the node at point.

9.1 Using the Cached Information

It is common to use take reference notes for academic papers. To designate the node to be the canonical node for the academic paper, we can use its unique citation key:

* Probabilistic Robotics
:PROPERTIES:
:ID:       51b7b82c-bbb4-4822-875a-ed548cffda10
:ROAM_REFS: @thrun2005probabilistic
:END:

or

* Probabilistic Robotics
:PROPERTIES:
:ID:       51b7b82c-bbb4-4822-875a-ed548cffda10
:ROAM_REFS: [cite:@thrun2005probabilistic]
:END:

for org-cite, or:

* Probabilistic Robotics
:PROPERTIES:
:ID:       51b7b82c-bbb4-4822-875a-ed548cffda10
:ROAM_REFS: cite:thrun2005probabilistic
:END:

for org-ref.

When another node has a citation for that key, we can see it using the Reflinks section of the Org-roam buffer.

Extension developers may be interested in retrieving the citations within their notes. This information can be found within the citation table of the Org-roam database.

10.1 Completing within Link Brackets

Completions within link brackets are provided by org-roam-complete-link-at-point.

The completion candidates are the titles and aliases for all Org-roam nodes. Upon choosing a candidate, a roam:Title link will be inserted, linking to node of choice.

10.2 Completing anywhere

The same completions can be triggered anywhere for the symbol at point if not within a bracketed link. This is provided by org-roam-complete-everywhere. Similarly, the completion candidates are the titles and aliases for all Org-roam nodes, and upon choosing a candidate a roam:Title link will be inserted linking to the node of choice.

This is disable by default. To enable it, set org-roam-completion-everywhere to t:

(setq org-roam-completion-everywhere t)

Variable: org-roam-completion-everywhere ¶

When non-nil, provide link completion matching outside of Org links.

12.1 Template Walkthrough

To demonstrate the additions made to org-capture templates. Here, we explain the default template, reproduced below. You will find most of the elements of the template are similar to org-capture templates.

(("d" "default" plain "%?"
  :target (file+head "%<%Y%m%d%H%M%S>-${slug}.org"
                     "#+title: ${title}\n")
  :unnarrowed t))

• The template has short key "d". If you have only one template, org-roam automatically chooses this template for you.
• The template is given a description of "default".
• plain text is inserted. Other options include Org headings via entry.
• Notice that the target that’s usually in Org-capture templates is missing here.
• "%?" is the template inserted on each call to org-roam-capture-. This template means don’t insert any content, but place the cursor here.
• :target is a compulsory specification in the Org-roam capture template. The first element of the list indicates the type of the target, the second element indicates the location of the captured node, and the rest of the elements indicate prefilled template that will be inserted and the position of the point will be adjusted for. The latter behavior varies from type to type of the capture target.
• :unnarrowed t tells org-capture to show the contents for the whole file, rather than narrowing to just the entry. This is part of the Org-capture templates.

See the org-roam-capture-templates documentation for more details and customization options.

12.2 Org-roam Template Expansion

Org-roam’s template definitions also extend org-capture’s template syntax, to allow prefilling of strings. We have seen a glimpse of this in Template Walkthrough.

Org-roam provides the ${foo} syntax for substituting variables with known strings. ${foo}’s substitution is performed as follows:

• If foo is a function, foo is called with the current node as its argument.
• Else if org-roam-node-foo is a function, foo is called with the current node as its argument. The org-roam-node- prefix defines many of Org-roam’s node accessors such as org-roam-node-title and org-roam-node-level.
• Else look up org-roam-capture--info for foo. This is an internal variable that is set before the capture process begins.
• If none of the above applies, read a string using completing-read.
  • Org-roam also provides the ${foo=default_val} syntax, where if a default value is provided, will be the initial value for the foo key during minibuffer completion.

One can check the list of available keys for nodes by inspecting the org-roam-node struct. At the time of writing, it is:

(cl-defstruct (org-roam-node (:constructor org-roam-node-create)
                             (:copier nil))
  "A heading or top level file with an assigned ID property."
  file file-hash file-atime file-mtime
  id level point todo priority scheduled deadline title properties olp
  tags aliases refs)

This makes ${file}, ${file-hash} etc. all valid substitutions.

13.1 org-roam-protocol

Org-roam provides extensions for capturing content from external applications such as the browser, via org-protocol. Org-roam extends org-protocol with 2 protocols: the roam-node and roam-ref protocols.

• Installation
• The roam-node protocol
• The roam-ref protocol

(require 'org-roam-protocol)

[Desktop Entry]
Name=Org-Protocol
Exec=emacsclient %u
Icon=emacs-icon
Type=Application
Terminal=false
MimeType=x-scheme-handler/org-protocol

xdg-mime default org-protocol.desktop x-scheme-handler/org-protocol

sudo mkdir -p /etc/opt/chrome/policies/managed/
sudo tee /etc/opt/chrome/policies/managed/external_protocol_dialog.json >/dev/null <<'EOF'
{
  "ExternalProtocolDialogShowAlwaysOpenCheckbox": true
}
EOF
sudo chmod 644 /etc/opt/chrome/policies/managed/external_protocol_dialog.json

on open location this_URL
    set EC to "/usr/local/bin/emacsclient --no-wait "
    set filePath to quoted form of this_URL
    do shell script EC & filePath
    tell application "Emacs" to activate
end open location

<key>CFBundleURLTypes</key>
<array>
  <dict>
    <key>CFBundleURLName</key>
    <string>org-protocol handler</string>
    <key>CFBundleURLSchemes</key>
    <array>
      <string>org-protocol</string>
    </array>
  </dict>
</array>

defaults write com.google.Chrome ExternalProtocolDialogShowAlwaysOpenCheckbox -bool true

defaults write com.apple.LaunchServices/com.apple.launchservices.secure LSHandlers -array-add \
'{"LSHandlerPreferredVersions" = { "LSHandlerRoleAll" = "-"; }; LSHandlerRoleAll = "org.yourusername.OrgProtocol"; LSHandlerURLScheme = "org-protocol";}'

REGEDIT4

[HKEY_CLASSES_ROOT\org-protocol]
@="URL:Org Protocol"
"URL Protocol"=""
[HKEY_CLASSES_ROOT\org-protocol\shell]
[HKEY_CLASSES_ROOT\org-protocol\shell\open]
[HKEY_CLASSES_ROOT\org-protocol\shell\open\command]
@="\"C:\\Windows\\System32\\wsl.exe\" emacsclient \"%1\""

@="\"c:\\path\\to\\emacs\\bin\\emacsclientw.exe\"  \"%1\""

Previous: The roam-node protocol, Up: org-roam-protocol   [Index]

13.1.3 The roam-ref protocol

This protocol finds or creates a new note with a given ROAM_REFS:

To use this, create the following bookmarklet in your browser:

javascript:location.href =
    'org-protocol://roam-ref?template=r&ref='
    + encodeURIComponent(location.href)
    + '&title='
    + encodeURIComponent(document.title)
    + '&body='
    + encodeURIComponent(window.getSelection())

or as a keybinding in qutebrowser in , using the config.py file (see Configuring qutebrowser):

config.bind("<Ctrl-r>", "open javascript:location.href='org-protocol://roam-ref?template=r&ref='+encodeURIComponent(location.href)+'&title='+encodeURIComponent(document.title)")

where template is the template key for a template in org-roam-capture-ref-templates (see The Templating System).

---

13.2 org-roam-graph

Org-roam provides basic graphing capabilities to explore interconnections between notes, in org-roam-graph. This is done by performing SQL queries and generating images using Graphviz. The graph can also be navigated: see org-roam-protocol.

The entry point to graph creation is org-roam-graph.

Function: org-roam-graph & optional arg node ¶

Build and display a graph for NODE. ARG may be any of the following values:

• nil show the full graph.
• integer an integer argument N will show the graph for the connected components to node up to N steps away.

User Option: org-roam-graph-executable ¶

Path to the graphing executable (in this case, Graphviz). Set this if Org-roam is unable to find the Graphviz executable on your system.

You may also choose to use neato in place of dot, which generates a more compact graph layout.

User Option: org-roam-graph-viewer ¶

Org-roam defaults to using Firefox (located on PATH) to view the SVG, but you may choose to set it to:

• A string, which is a path to the program used
• a function accepting a single argument: the graph file path.

nil uses view-file to view the graph.

If you are using WSL2 and would like to open the graph in Windows, you can use the second option to set the browser and network file path:

(setq org-roam-graph-viewer
    (lambda (file)
      (let ((org-roam-graph-viewer "/mnt/c/Program Files/Mozilla Firefox/firefox.exe"))
        (org-roam-graph--open (concat "file://///wsl$/Ubuntu" file)))))

• Graph Options

13.3 org-roam-dailies

Org-roam provides journaling capabilities akin to Org-journal with org-roam-dailies.

• Configuration
• Usage

(setq org-roam-dailies-directory "daily/")

(setq org-roam-dailies-capture-templates
      '(("d" "default" entry
         "* %?"
         :target (file+head "%<%Y-%m-%d>.org"
                            "#+title: %<%Y-%m-%d>\n"))))

13.4 org-roam-export

Because Org-roam files are plain org files, they can be exported easily using org-export to a variety of formats, including html and pdf. However, Org-roam relies heavily on ID links, which Org’s html export has poor support of. To fix this, Org-roam provides a bunch of overrides to better support export. To use them, simply run:

(require 'org-roam-export)

14.1 Garbage Collection

During the cache-build process, Org-roam generates a lot of in-memory data-structures (such as the Org file’s AST), which are discarded after use. These structures are garbage collected at regular intervals (see (elisp)info:elisp#Garbage Collection).

Org-roam provides the option org-roam-db-gc-threshold to temporarily change the threshold value for GC to be triggered during these memory-intensive operations. To reduce the number of garbage collection processes, one may set org-roam-db-gc-threshold to a high value (such as most-positive-fixnum):

(setq org-roam-db-gc-threshold most-positive-fixnum)

15.1 Browsing History with winner-mode

winner-mode is a global minor mode that allows one to undo and redo changes in the window configuration. It is included with GNU Emacs since version 20.

winner-mode can be used as a simple version of browser history for Org-roam. Each click through org-roam links (from both Org files and the backlinks buffer) causes changes in window configuration, which can be undone and redone using winner-mode. To use winner-mode, simply enable it, and bind the appropriate interactive functions:

(winner-mode +1)
(define-key winner-mode-map (kbd "<M-left>") #'winner-undo)
(define-key winner-mode-map (kbd "<M-right>") #'winner-redo)

15.2 Versioning Notes

Since Org-roam notes are just plain text, it is trivial to track changes in your notes database using version control systems such as Git. Simply initialize org-roam-directory as a Git repository, and commit your files at regular or appropriate intervals. Magit is a great interface to Git within Emacs.

In addition, it may be useful to observe how a particular note has evolved, by looking at the file history. Git-timemachine allows you to visit historic versions of a tracked Org-roam note.

15.3 Full-text search with Deft

Deft provides a nice interface for browsing and filtering org-roam notes.

(use-package deft
  :after org
  :bind
  ("C-c n d" . deft)
  :custom
  (deft-recursive t)
  (deft-use-filter-string-for-filename t)
  (deft-default-extension "org")
  (deft-directory org-roam-directory))

The Deft interface can slow down quickly when the number of files get huge. Notdeft is a fork of Deft that uses an external search engine and indexer.

15.4 Org-journal

Org-journal provides journaling capabilities to Org-mode. A lot of its functionalities have been incorporated into Org-roam under the name org-roam-dailies. It remains a good tool if you want to isolate your verbose journal entries from the ideas you would write on a scratchpad.

(use-package org-journal
  :bind
  ("C-c n j" . org-journal-new-entry)
  :custom
  (org-journal-date-prefix "#+title: ")
  (org-journal-file-format "%Y-%m-%d.org")
  (org-journal-dir "/path/to/journal/files/")
  (org-journal-date-format "%A, %d %B %Y"))

15.5 Org-download

Org-download lets you screenshot and yank images from the web into your notes:

Figure: org-download

(use-package org-download
  :after org
  :bind
  (:map org-mode-map
        (("s-Y" . org-download-screenshot)
         ("s-y" . org-download-yank))))

15.6 mathpix.el

mathpix.el uses Mathpix’s API to convert clips into latex equations:

Figure: mathpix

(use-package mathpix.el
  :straight (:host github :repo "jethrokuan/mathpix.el")
  :custom ((mathpix-app-id "app-id")
           (mathpix-app-key "app-key"))
  :bind
  ("C-x m" . mathpix-screenshot))

15.7 Org-noter / Interleave

Org-noter and Interleave are both projects that allow synchronised annotation of documents (PDF, EPUB etc.) within Org-mode.

15.8 Bibliography

Org 9.5 added native citation and bibliography functionality, called “org-cite”, which org-roam supports.

org-roam-bibtex offers tight integration between org-ref, helm-bibtex and org-roam. This helps you manage your bibliographic notes under org-roam.

For example, though helm-bibtex provides the ability to visit notes for bibliographic entries, org-roam-bibtex extends it with the ability to visit the file with the right ROAM_REFS.

15.9 Spaced Repetition

Org-fc is a spaced repetition system that scales well with a large number of files. Other alternatives include org-drill, and pamparam.

To use Anki for spaced repetition, anki-editor allows you to write your cards in Org-mode, and sync your cards to Anki via anki-connect.

16.1 How do I have more than one Org-roam directory?

Emacs supports directory-local variables, allowing the value of org-roam-directory to be different in different directories. It does this by checking for a file named .dir-locals.el.

To add support for multiple directories, override the org-roam-directory variable using directory-local variables. This is what .dir-locals.el may contain:

((nil . ((org-roam-directory . "/path/to/alt/org-roam-dir")
         (org-roam-db-location . "/path/to/alt/org-roam-dir/org-roam.db"))))

Note org-roam-directory and org-roam-db-location should be an absolute path, not relative.

Alternatively, use eval if you wish to call functions:

((nil . ((eval . (setq-local
                  org-roam-directory (expand-file-name (locate-dominating-file
                                                        default-directory ".dir-locals.el"))))
         (eval . (setq-local
                  org-roam-db-location (expand-file-name "org-roam.db"
                                                         org-roam-directory))))))

All files within that directory will be treated as their own separate set of Org-roam files. Remember to run org-roam-db-sync from a file within that directory, at least once.

16.2 How do I create a note whose title already matches one of the candidates?

This situation arises when, for example, one would like to create a note titled “bar” when “barricade” already exists.

The solution is dependent on the mini-buffer completion framework in use. Here are the solutions:

• Ivycall ivy-immediate-done, typically bound to C-M-j. Alternatively, set ivy-use-selectable-prompt to t, so that “bar” is now selectable.
• HelmOrg-roam should provide a selectable “[?] bar” candidate at the top of the candidate list.

16.3 How can I stop Org-roam from creating IDs everywhere?

Other than the interactive commands that Org-roam provides, Org-roam does not create IDs everywhere. If you are noticing that IDs are being created even when you don’t want them to be (e.g. when tangling an Org file), check the value you have set for org-id-link-to-org-use-id: setting it to 'create-if-interactive is a popular option.

16.4 How do I migrate from Roam Research?

Fabio has produced a command-line tool that converts markdown files exported from Roam Research into Org-roam compatible markdown. More instructions are provided in the repository.

16.5 How to migrate from Org-roam v1?

Those coming from Org-roam v1 will do well treating v2 as entirely new software. V2 has a smaller core and fewer moving parts, while retaining the bulk of its functionality. It is recommended to read the documentation above about nodes.

It is still desirable to migrate notes collected in v1 to v2. To migrate your v1 notes to v2, use ‘M-x org-roam-migrate-wizard’. This blog post provides a good overview of what’s new in v2 and how to migrate.

Essentially, to migrate notes from v1 to v2, one must:

• Add IDs to all existing notes. These are located in top-level property drawers (Although note that in v2, not all files need to have IDs).
• Update the Org-roam database to conform to the new schema.
• Replace #+ROAM_KEY into the ROAM_REFS property
• Replace #+ROAM_ALIAS into the ROAM_ALIASES property
• Move #+ROAM_TAGS into the #+FILETAGS property for file-level nodes, and the ROAM_TAGS property for headline nodes
• Replace existing file links with ID links.

16.6 How do I publish my notes with an Internet-friendly graph?

The default graph builder creates a graph with an org-protocol handler which is convenient when you’re working locally but inconvenient when you want to publish your notes for remote access. Likewise, it defaults to displaying the graph in Emacs which has the exact same caveats. This problem is solvable in the following way using org-mode’s native publishing capability:

• configure org-mode to publish your org-roam notes as a project.
• create a function that overrides the default org-protocol link creation function(‘org-roam-default-link-builder’).
• create a hook that’s called at the end of graph creation to copy the generated graph to the appropriate place.

The example code below is used to publish to a local directory where a separate shell script copies the files to the remote site.

• Configure org-mode for publishing
• Overriding the default link creation function
• Copying the generated file to the export directory

(defun roam-sitemap (title list)
  (concat "#+OPTIONS: ^:nil author:nil html-postamble:nil\n"
          "#+SETUPFILE: ./simple_inline.theme\n"
          "#+TITLE: " title "\n\n"
          (org-list-to-org list) "\nfile:sitemap.svg"))

(setq my-publish-time 0)   ; see the next section for context
(defun roam-publication-wrapper (plist filename pubdir)
  (org-roam-graph)
  (org-html-publish-to-html plist filename pubdir)
  (setq my-publish-time (cadr (current-time))))

(setq org-publish-project-alist
  '(("roam"
     :base-directory "~/roam"
     :auto-sitemap t
     :sitemap-function roam-sitemap
     :sitemap-title "Roam notes"
     :publishing-function roam-publication-wrapper
     :publishing-directory "~/roam-export"
     :section-number nil
     :table-of-contents nil
     :style "<link rel=\"stylesheet\" href=\"../other/mystyle.cs\" type=\"text/css\">")))

(defun org-roam-custom-link-builder (node)
  (let ((file (org-roam-node-file node)))
    (concat (file-name-base file) ".html")))

(setq org-roam-graph-link-builder 'org-roam-custom-link-builder)

(add-hook 'org-roam-graph-generation-hook
          (lambda (dot svg) (if (< (- (cadr (current-time)) my-publish-time) 5)
                                (progn (copy-file svg "~/roam-export/sitemap.svg" 't)
                                       (kill-buffer (file-name-nondirectory svg))
                                       (setq my-publish-time 0)))))

16.7 I’m seeing this “Selecting deleted buffer” error. What do I do?

The “selecting deleted buffer” error usually occurs when you don’t have a working emacsql-sqlite executable. Org-roam relies on this executable to function properly, and doesn’t catch this error. This issue is most commonly seen on Windows setups. You can browse through the various GitHub issues posted about this here.

To fix this, you can try the following:

• If on Windows, try replacing your system binary with this one that has been proven to work
• Use the emacsql-sqlite3 option rather than compiling your own emacsql binary (see How to cache).

17.1 Org-roam’s Design Principle

Org-roam is primarily motivated by the need for a dual representation. We (humans) love operating in a plain-text environment. The syntax rules of Org-mode are simple and fit snugly within our brain. This also allows us to use the tools and packages we love to explore and edit our notes. Org-mode is simply the most powerful plain-text format available, with support for images, LaTeX, TODO planning and much more.

But this plain-text format is simply ill-suited for exploration of these notes: plain-text is simply not amenable for answering large-scale, complex queries (e.g. how many tasks do I have that are due by next week?). Interfaces such as Org-agenda slow to a crawl when the number of files becomes unwieldy, which can quickly become the case.

At its core, Org-roam provides a database abstraction layer, providing a dual representation of what’s already available in plain-text. This allows us (humans) to continue working with plain-text, while programs can utilize the database layer to perform complex queries. These capabilities include, but are not limited to:

• link graph traversal and visualization
• Instantaneous SQL-like queries on headlines
  • What are my TODOs, scheduled for X, or due by Y?
• Accessing the properties of a node, such as its tags, refs, TODO state or priority

All of these functionality is powered by this database abstraction layer. Hence, at its core Org-roam’s primary goal is to provide a resilient dual representation that is cheap to maintain, easy to understand, and is as up-to-date as it possibly can. Org-roam also then exposes an API to this database abstraction layer for users who would like to perform programmatic queries on their Org files.

17.2 Building Extensions and Advanced Customization of Org-roam

Because Org-roam’s core functionality is small, it is possible and sometimes desirable to build extensions on top of it. These extensions may one or more of the following functionalities:

• Access to Org-roam’s database
• Usage/modification of Org-roam’s interactive commands

Org-roam provides no guarantees that extensions will continue to function as Org-roam evolves, but by following these simple rules, extensions can be made robust to local changes in Org-roam.

• Extensions should not modify the database schema. Any extension that requires the caching of additional data should make a request upstream to Org-roam.
• Extensions requiring access to the database should explicitly state support for the database version (org-roam-db-version), and only conditionally load when support is available.

• Accessing the Database
• Accessing and Modifying Nodes
• Extending the Capture System

(org-roam-db-query [:select * :from nodes])

(cl-defmethod org-roam-node-namespace ((node org-roam-node))
  "Return the namespace for NODE.
The namespace is the final directory of the file for the node."
  (file-name-nondirectory
   (directory-file-name
    (file-name-directory (org-roam-node-file node)))))

(defun org-roam-dailies--capture (time &optional goto)
  "Capture an entry in a daily-note for TIME, creating it if necessary.

When GOTO is non-nil, go the note without creating an entry."
  (org-roam-capture- :goto (when goto '(4))
                     :node (org-roam-node-create)
                     :templates org-roam-dailies-capture-templates
                     :props (list :override-default-time time))
  (when goto (run-hooks 'org-roam-dailies-find-file-hook)))

18.1 Note-taking Workflows

• Books
  • How To Take Smart Notes
• Articles
  • The Zettelkasten Method - LessWrong 2.0
  • Building a Second Brain in Roam…And Why You Might Want To : RoamResearch
  • Roam Research: Why I Love It and How I Use It - Nat Eliason
  • Adam Keesling’s Twitter Thread
  • How To Take Smart Notes With Org-mode · Jethro Kuan
• Threads
  • Ask HN: How to Take Good Notes
• Videos
  • How to Use Roam to Outline a New Article in Under 20 Minutes

18.2 Ecosystem